root/hydranode-oldbld/configure.ac

#                                               -*- Autoconf -*-
# Process this file with autoconf to produce a configure script.

AC_PREREQ(2.56)
AC_INIT(hydranode, 0.1.1, madcat@hydranode.com)
AC_CANONICAL_TARGET
AM_INIT_AUTOMAKE(hydranode, 0.1.1)
AC_CONFIG_SRCDIR([src/hydranode.cpp])
AM_CONFIG_HEADER([config.h])

with_pic="no";

CXXFLAGS=`echo $CXXFLAGS | sed s/-O2//`; # Gets rid of default -O2

# Enable all default warnings
CXXFLAGS="$CXXFLAGS -W -Wall -Wno-return-type -Wno-long-long -Wpointer-arith -pedantic"

# 64-bit file I/O please
CPPFLAGS="$CPPFLAGS -D_LARGE_FILES -D_FILE_OFFSET_BITS=64"

# Checks for programs.
AC_PROG_CXX
AC_PROG_MAKE_SET
AC_DISABLE_STATIC
AC_PROG_LIBTOOL
AC_LANG(C++)
AC_PREFIX_DEFAULT(/opt/hydranode)
_AC_SRCPATHS(["."])

AC_MSG_CHECKING([compiler version])
AC_PREPROC_IFELSE(
        [AC_LANG_PROGRAM([[#if !defined __GNUC__
  #error Not GNU compiler
#elif __GNUC__ < 3
  #error Need GCC 3 or newer
#elif __GNUC__ == 3 && __GNUC_MINOR__ < 2
  #error Need GCC 3.2 or newer, found __GNUC__ __GNU__MINOR__
#endif                  ]])],
        [AC_MSG_RESULT([ok])],
        [AC_MSG_FAILURE([hydranode requires g++ 3.2 or newer])])

trace_dflt="yes"

AC_ARG_ENABLE(,,)
AC_ARG_ENABLE(, [Customization:],)
AC_ARG_ENABLE(debug,
        [  --enable-debug           Enable code debugging     [[default=yes]] ],
        debug="$enableval",    debug="yes"  )
AC_ARG_ENABLE(trace,
        [  --enable-trace           Enable trace logging      [[default=no ]]  ],
        [trace="$enableval" && trace_dflt="no"],    trace="no"   )
AC_ARG_ENABLE(optimize,
        [  --enable-optimize        Enable code optimizations [[default=no ]] ],
        optimize="$enableval", optimize="no")
AC_ARG_ENABLE(some_optimize,
        [  --enable-some_optimize   Enable some optimizations [[default=no ]] ],
        some_optimize="$enableval",  some_optimize="no")
AC_ARG_ENABLE(colors,
        [  --enable-colors          Enable coloured output    [[default=yes]] ],
        colors="$enableval",   colors="yes" )
AC_ARG_ENABLE(profile,
        [  --enable-profile         Enable code profiling     [[default=no ]] ],
         profile="$enableval",  profile="no" )
AC_ARG_ENABLE(hexdumps,
        [  --enable-hexdumps        Enable packet hexdumps    [[default=no ]] ],
         hexdumps="$enableval", hexdumps="no")
AC_ARG_WITH(builtin_boost,
            [  --with-builtin_boost    Use built-in Boost library    [[default=no]]],
            [builtin_boost=$withval], [builtin_boost=false]
)
dnl This is here and not in boost.m4 'cos otherwise it breaks when both
dnl builtin_boost and with-boost args are specified.
AC_ARG_WITH(boost,
    AC_HELP_STRING(
        [--with-boost=PATH],
        [Absolute path name where the Boost C++ libraries reside]),
        [BOOST_ROOT=$withval], [BOOST_ROOT="/usr"]
)

AC_ARG_WITH(builtin,
        [  --with-builtin=MODULES  Modules that shall be built-in            ],
        builtin="$builtin $withval", builtin="")
AC_ARG_ENABLE(static,
        [  --enable-static          Enable static linking     [[default=no ]] ],
        static="$enableval", static="no")

AC_MSG_CHECKING([for --enable-optimize])
AC_MSG_RESULT($optimize)
if test $optimize == yes; then CPPFLAGS="$CPPFLAGS -O3"; fi;

AC_MSG_CHECKING([for --enable-some_optimize])
AC_MSG_RESULT($some_optimize)
if test $some_optimize == yes; then CPPFLAGS="$CPPFLAGS -O0"; fi

AC_MSG_CHECKING([for --enable-debug])
AC_MSG_RESULT([$debug])
if test $debug == yes; then
        CXXFLAGS="$CXXFLAGS -g -ggdb";
else
        CXXFLAGS="$CXXFLAGS -DNDEBUG";
fi

AC_MSG_CHECKING([for --enable-trace])
AC_MSG_RESULT([$trace])
if test $trace == no; then CXXFLAGS="$CXXFLAGS -DNTRACE"; fi

AC_MSG_CHECKING([for --enable-profile])
AC_MSG_RESULT($profile)
if test $profile == yes; then CXXFLAGS="$CXXFLAGS -p -pg"; fi

AC_MSG_CHECKING([for --enable-colors])
AC_MSG_RESULT($colors)
if test $colors == yes; then
    AC_DEFINE([__ANSI_COLORS__], [], [Define if you want coloured runtime output])
fi

AC_MSG_CHECKING([for --enable-static])
AC_MSG_RESULT($static)
if test $static == yes; then
        LDFLAGS="$LDFLAGS -static";
        AC_DEFINE([STATIC_BUILD], [], [Define when making a static build])
fi

AC_MSG_CHECKING([for --enable-hexdumps])
AC_MSG_RESULT($hexdumps)
if test $hexdumps == yes; then
        AC_DEFINE([HEXDUMPS], [], [Define to get packet hexdumps])
fi

AM_CONDITIONAL([STATIC_BUILD], test x$static = xyes)

dnl Check Boost C++ libs
if test x$builtin_boost != xyes; then
        RS_BOOST([1.32.0],[],[AC_MSG_ERROR(Boost C++ libraries not found)])
fi
if test x$builtin_boost != xyes; then
        RS_BOOST_THREAD([], [builtin_boost=yes])
        RS_BOOST_DATETIME([], [builtin_boost=yes])
        RS_BOOST_SIGNALS([], [builtin_boost=yes])
        RS_BOOST_FILESYSTEM([], [builtin_boost=yes])
        RS_BOOST_PROGRAM_OPTIONS([], [builtin_boost=yes])
fi
if test -z $BOOST_ROOT || test $BOOST_ROOT = "/usr"; then
        boost_path="$HOME/boost_1_32_0";
else
        boost_path=$BOOST_ROOT
fi
if test x$builtin_boost = xyes; then
        BOOST_CPPFLAGS="-I$boost_path"
fi

AM_CONDITIONAL(BUILTIN_BOOST, test x$builtin_boost = xyes)
AC_SUBST(boost_path, $boost_path)

CPPFLAGS="$CPPFLAGS $BOOST_CPPFLAGS"
LDFLAGS="$LDFLAGS $BOOST_LIBS_R";

dnl Checks for libraries.
case $target_os in
        *bsd*)
                AC_CHECK_LIB([c], [dlopen], [LIBS="-lc";
                        AC_DEFINE(HAVE_LIBDL, 1, Define if you have libdl)])
                ;;
        *)
                AC_CHECK_LIB([dl], [dlopen], [LIBS="-ldl";
                        AC_DEFINE(HAVE_LIBDL, 1, Define if you have libdl)])
                ;;
esac
dnl AC_CHECK_LIB([pthread], [pthread_create])
AC_CHECK_LIB([z], [compress2], [], [
        builtin_modules="$builtin_modules ../zlib/built-in.o"
        builtin_dirs="$builtin_dirs ../zlib"
        builtin_zlib=true
        CPPFLAGS="$CPPFLAGS -I$ac_abs_top_srcdir/zlib"
])

# Checks for header files.
AC_CHECK_HEADERS([stdint.h inttypes.h])
AC_CHECK_HEADERS([arpa/inet.h fcntl.h netinet/in.h sys/socket.h sys/time.h sys/timeb.h])
AC_CHECK_HEADERS([signal.h execinfo.h])
AC_CHECK_HEADERS([byteswap.h libkern/OSByteOrder.h])

# Checks for library functions.
AC_CHECK_FUNCS([gettimeofday ftime memset sigaction setsid fork])

AC_SUBST(module_cpp, "-D__MODULE__")

# Adjust compiler/linker flags as neccesery for platform
case $target_os in
        darwin*)
                CPPFLAGS="$CPPFLAGS -D__MAC__ -Wno-long-double"
                LDFLAGS="$LDFLAGS -framework Carbon"
                AC_SUBST(core_ld, "$LIBS")
                AC_SUBST(module_ld, "-bundle -bundle_loader $ac_abs_top_builddir/src/hydranode")
                ;;
        mingw32* | cygwin)
                CPPFLAGS="$CPPFLAGS -mthreads -DBOOST_THREAD_BUILD_LIB"
                LDFLAGS="$LDFLAGS"
                AC_SUBST(core_ld, "/mingw/lib/libws2_32.a")
                ;;
        linux* | *bsd*)
                CPPFLAGS="$CPPFLAGS -pthread"
                LDFLAGS="$LDFLAGS $LIBS -lpthread";
                if test $static != yes; then
                        core_ldflags="$core_ldflags -rdynamic";
                fi
                AC_SUBST(core_ld, $core_ldflags)
                AC_SUBST(module_ld, "-shared")
                ;;
        solaris*)
                CPPFLAGS="$CPPFLAGS -pthreads"
                LDFLAGS="$LDFLAGS -pthreads"
                core_ldflags="$LIBS -lsocket -lrt -lnsl"
                if test x$with_gnu_ld = xtrue; then
                        core_ldflags="$core_ldflags  -Wl,-export-dynamic";
                fi
                AC_SUBST(core_ld, $core_ldflags)
                AC_SUBST(module_cpp, "-fPIC")
                AC_SUBST(module_ld, "-shared")
                ;;
        *)
                AC_MSG_ERROR([Unsupported platform $target_os, please report this.])
                ;;
esac

build_modules="ed2k hnsh" # Default modules
case $with_ed2k in no) build_modules=`echo $build_modules | sed s/ed2k//`;; esac
case $with_hnsh in no) build_modules=`echo $build_modules | sed s/hnsh//`;; esac
case $with_minimal in yes) build_modules="$build_modules minimal";; esac
case $with_ftp in yes) build_modules="$build_modules ftp";; esac
case $with_dc in yes) build_modules="$build_modules dc";; esac
case $with_http in yes) build_modules="$build_modules http";; esac
case $with_cgcomm in yes) build_modules="$build_modules cgcomm";; esac
case $with_mailnotify in yes) build_modules="$build_modules mailnotify";; esac

builtin=`echo $builtin | sed 's/,/\ /'` # Replace commas with spaces
for i in $builtin; do
        builtin_modules="$builtin_modules $ac_abs_top_builddir/modules/$i/built-in.o";
        builtin_dirs="$builtin_dirs $ac_abs_top_builddir/modules/$i";

        # If built-in, don't build dynamic version anymore
        build_modules=`echo $build_modules | sed s/$i//`

        case $i in
                ed2k) AC_SUBST(ed2k_cpp, [-DBUILT_IN]);;
                hnsh) AC_SUBST(hnsh_cpp, [-DBUILT_IN]);;
                minimal) AC_SUBST(minimal_cpp, [-DBUILT_IN]);;
                ftp) AC_SUBST(ftp_cpp, [-DBUILT_IN]);;
                dc) AC_SUBST(dc_cpp, [-DBUILT_IN]);;
                cgcomm) AC_SUBST(cgcomm_cpp, [-DBUILT_IN]);;
                http) AC_SUBST(http_cpp, [-DBUILT_IN]);;
                mailnotify) AC_SUBST(mailnotify_cpp, [-DBUILT_IN]);;
        esac
        builtin_flag=built-in.o
done;
builtin_modules_names=$builtin # Cache it here before it gets overwritten

AC_SUBST(build_modules, $build_modules)
AC_SUBST(builtin_modules, $builtin_modules)
AC_SUBST(builtin_module_dirs, $builtin_dirs)
AC_SUBST(builtin, $builtin_flag)

test "x$prefix" = xNONE && prefix=$ac_default_prefix
AC_DEFINE_UNQUOTED([MODULE_DIR], "$prefix/lib", [Path to modules])

# Due to the design of Autoconf, all modules must be listed here, as well as
# in modules/Makefile.am, under EXTRA_SUBDIRS
AC_CONFIG_FILES([Makefile
                modules/Makefile
                modules/ed2k/Makefile
                modules/hnsh/Makefile
                modules/minimal/Makefile
                modules/mailnotify/Makefile
                zlib/Makefile
                src/Makefile
                tests/Makefile
                tests/test-workthread/Makefile
                tests/test-range/Makefile
                tests/test-ipfilter/Makefile
                tests/test-partdata/Makefile
                tests/test-hasher/Makefile
                tests/test-hash/Makefile
                tests/test-config/Makefile
                tests/test-metadata/Makefile
])
AC_OUTPUT

echo
echo "Configured Hydranode $VERSION for \`$target'"
echo
echo -e "  Should optimizations be enabled?         $optimize"
echo -e "  Should debugging be enabled?             $debug"
echo -e "  Should trace code be enabled?            $trace"
echo -e "  Which dynamic modules should be built?   $build_modules"
echo -e "  Which modules should be built-in?        $builtin_modules_names"
echo -e "  Which libraries should be used?"
if test x$builtin_boost = xyes; then
        echo -e "                                           Boost (built-in)"
else
        echo -e "                                           Boost (system)"
fi
if test x$builtin_zlib = xtrue; then
        echo -e "                                           Zlib (built-in)"
else
        echo -e "                                           Zlib (system)"
fi

if test x$builtin_boost = xyes; then
        if ! test -d $boost_path ; then
                echo ""
                echo "ERROR: Boost libraries not detected on system."
                echo "ERROR: Boost libraries source not found at '$boost_path'."
                echo -n "Unable to continue; "
                echo "Boost libraries are available from http://www.boost.org/."
                echo ""
                exit 1;
        else
                echo "  Where are Boost library sources?         $boost_path"
        fi
fi
echo